** user=**** 
** password=**** 
** package=spss
** project=les

set printback=listing .

* SPSS US LES 1997 : Example CAMSIS matching to US 97 data.
*(note that this uses different index var and educ from us90).
*(index var is soc80 and is only at TITLE ONLY level).

get file= us97e .
* Current occ unit (soc80's)=fj04. 
* in this example only, can ignore employment status diffs.
*[no status derivation].


* Key indexing variable is soc80.
compute soc80=-999.
if (fj04 > 0 ) soc80=fj04 .
temp.
select if (fj04 > 0 ) .
means tables=soc80 by db02  .


* Match this file with CAMSIS file using index var. 
sort cases by soc80.
sav out= cstemp .
get file="u:/camsis/csuses97.sav" .
descriptives var=all.
sort cases by soc80.
match files table=* /in=csocc 
     /file=cstemp /in=source /by=soc80.
fre var=csocc source.
cro csocc by source.
select if (source=1).
* (this removes those soc80 values which are not
*   represented in the LES sample).
cro source by db02. 



* Current values are within gender. 
compute cgentcs=-999.
if (db02=1) cgentcs=htcs .
if (db02=2) cgentcs=wtcs .
compute cgenscs=-999.
*if (db02=1) cgenscs=hiscs .
*if (db02=2) cgenscs=wiscs .


* Check distributions of vars. 
descriptives var= soc80 cgentcs cgenscs siops isei .
temp.
select if (fj04 > 0) .
descriptives var= soc80 cgentcs cgenscs siops isei.
temp.
select if (fj04 > 0 & siops > 0).
descriptives var=  soc80 cgentcs cgenscs siops isei . 
* note that the last summary shows us that a handful 
* of cases have occs  and camsis scores but have missing 
* siops scores by the ISMF translation.



* Quick assessment: compare values by an education recode.
compute educ=et01. 
recode educ (0, 31 thru 34=1) (35 thru 40=2) (41 thru 46=3)
                (else=-9) .
add value labels educ  1 "Primary or less" 2 "Intermediate" 
                3 "Degree level". 
variable label educ "education categories".
fre var= educ .

temp.
select if (fj04 > 0).
descriptives var= educ cgentcs cgenscs siops isei . 

temp. 
select if (fj04 > 0 & siops > 0 & db02=1).
means tables= cgentcs  siops isei by educ  
             /statistics=anova.

temp. 
select if (fj04 > 0 & siops > 0 & db02=2).
means tables= cgentcs siops isei by educ 
             /statistics=anova.


/* For interest here are the Eta-squared statistics with education from above:

Men: 
CAMSIS title only : 0.31
CAMSIS title by status : 0.NA
SIOPS : 0.27
ISEI: 0.33
Women: 
CAMSIS title only : 0.24
CAMSIS title by status : 0.NA
SIOPS : 0.20
ISEI: 0.18
 
*/