** user=**** 
** password=**** 
** package=spss
** project=les

set printback=listing .

* US LES 1990 : SPSS Example CAMSIS matching to US 90 data.

get file= us90e .
* Current occ unit (isco88's)=fj04. 
* (incomplete) Employment status info from fj02 and fj05.


* Derive employment status indicator.
compute status=fj02.
recode status (1=1) (3=5) (4=2) (else=9) .
if (fj05=1 & fj02=3) status=4 .
add value labels status 
    1 "Self-Employed, not incorporated"
   2 "Family Worker" 3 "Self-Employed, incorporated"
   4 "Government Employee" 5 "Other Employee" 
   9 "Unknown" .
variable label status "Employment status".
cro status by db02.


* Key indexing variable is iscobst.
compute iscobst=-999.
if (fj04 > 0 ) iscobst=(fj04*10) + status .
temp.
select if (fj04 > 0).
means tables=iscobst by status  .


* Match with CAMSIS files by index var. 
sort cases by iscobst.
sav out= cstemp .
get file="u:/camsis/csuses90.sav" .
descriptives var=all.
sort cases by iscobst.
match files table=* /in=csocc 
     /file=cstemp /in=source /by=iscobst.
fre var=csocc source.
cro csocc by source.
select if (source=1).
* (this removes those iscobst values which are not
*   represented in the LES sample).
cro source by db02. 


* Current values are within gender; 
* also can make a cross-gender CAMSIS variable : .
compute cgentcs=-999.
if (db02=1) cgentcs=htcs .
if (db02=2) cgentcs=wtcs .
compute cgenscs=-999.
if (db02=1) cgenscs=hscs .
if (db02=2) cgenscs=wscs .
descriptives var= iscobst cgentcs cgenscs siops isei .
temp.
select if (fj04 > 0) .
descriptives var= iscobst cgentcs cgenscs siops isei.
temp.
select if (fj04 > 0 & siops > 0).
descriptives var=  iscobst cgentcs cgenscs siops isei . 
* note that the last summary shows us that a handful 
* of cases have occs  and camsis scores but have missing 
* siops scores by the ISMF translation.


* Quick assessment: compare values by a US education recode.
compute educ=et01. 
recode educ (0, 1, 2=1) (3=2) (4=3) (else=-9) .
add value labels educ  1 "Primary or less" 2 "Intermediate" 
    3 "High or Degree level ". 
variable label educ "education categories".
fre var= educ  .

temp.
select if (fj04 > 0).
descriptives var= educ cgentcs cgenscs siops isei . 

temp. 
select if (fj04 > 0 & siops > 0 & db02=1).
means tables= cgentcs cgenscs siops isei by educ  
             /statistics=anova.

temp. 
select if (fj04 > 0 & siops > 0 & db02=2).
means tables= cgentcs cgenscs siops isei by educ 
             /statistics=anova.


/* For interest here are the Eta-squared statistics with 
education from above:

Men: 
CAMSIS title only : 0.27
CAMSIS title by status : 0.27
SIOPS : 0.23
ISEI: 0.27
Women: 
CAMSIS title only : 0.24
CAMSIS title by status : 0.23
SIOPS : 0.19
ISEI: 0.18
 
*/