** user=**** 
** password=**** 
** package=spss
** project=lis


* UK LIS 1991 : SPSS Example CAMSIS matching to UK 91 data.

get file= uc91p .
* Current occ unit (soc90)=pocc. 
* (incomplete) Employment status info from plfs and ptypewk.

* Derive employment status variable. 
compute status=plfs.
recode status (1=7) (2=3) (else=9).
if (ptypewk=1) status=1.
if (ptypewk=3 | ptypewk=16) status=2 .
if (ptypewk=2) status=4 .
if (ptypewk=4) status=5 .
if (ptypewk=8 | ptypewk=11) status=6 .
add value labels status 
   1 "Self-Employed gt 25 employees"
   2 "Self-Employed with employees" 
   3 "Self-Employed no employees" 
   4 "Manager, large"    5 "Manager, small"
   6 "Supervisor / foreman"    7 "Employee" 
   9 "Unknown".
variable label status "Employment status".
cro status by psex.

* Derive linking index variable. 
compute occbst=-999.
if (pocc > 0 ) occbst=pocc*10 + status .
temp.
select if (pocc > 0).
means tables=occbst by status /cells=min max count .


* Match with CAMSIS file using index variable. 
sort cases by occbst.
sav out= cstemp .
get file="u:/camsis/csukis91.sav".
descriptives var=all.
sort cases by occbst.
match files table=* /in=csocc 
     /file=cstemp /in=source /by=occbst.
fre var=csocc source.
select if (source=1).
* (this removes those occbst values which are not
*   represented in the LIS sample).
cro source by psex. 


* Current values are within gender. 
* also can make a cross-gender CAMSIS variable : .
compute cgentcs=-999.
if (psex=1) cgentcs=htcs.
if (psex=2) cgentcs=wtcs. 
compute cgenscs=-999.
if (psex=1) cgenscs=hscs.
if (psex=2) cgenscs=wscs. 


* Check overall distributions. 
descriptives var=occbst cgentcs cgenscs siops isei .
temp. 
select if (pocc > 0). 
descriptives var=occbst cgentcs cgenscs siops isei .
temp. 
select if (pocc > 0 & siops > 0). 
descriptives var=occbst cgentcs cgenscs siops isei .
fre var=egp. 
* note that the last summary shows us that a handful of cases 
* have occs and camsis scores but have missing siops 
* scores by the ISMF translation.
* note also that a lot more cases are missing on egp, because of 
* insufficient status info.


* Quick assessment (1): compare values by egp. 
temp.
select if (psex=1 & pocc > 0 & siops > 0).
summarize tables=cgentcs cgenscs siops isei by egp
     /cells=count mean /statistics=anova .
temp.
select if (psex=2 & pocc > 0 & siops > 0).
summarize tables=cgentcs cgenscs siops isei by egp
     /cells=count mean /statistics=anova .



* Quick assessment (2) : compare values by a UK education recode.
compute educ=peduc.
recode educ (0 thru 14=1) (15 thru 17=2) (18 thru 34=3) (else=-9).
add value labels educ  1 "0-14yrs" 2 "15-17yrs" 
  3 "18 or more years " -9 "Unknown". 
variable label educ "education categories".
fre var=  educ  .


descriptives var= educ cgentcs cgenscs siops isei .

temp. 
select if (pocc > 0 & siops > 0 & psex=1).
means tables= cgentcs cgenscs siops isei by educ  
             /statistics=anova.

temp. 
select if (pocc > 0 & siops > 0 & psex=2).
means tables= cgentcs cgenscs siops isei by educ 
             /statistics=anova.


/* For interest here are the Eta-squared statistics with education from above:

Men: 
CAMSIS title only : 0.23
CAMSIS title by status : 0.22
SIOPS : 0.19
ISEI: 0.22
Women: 
CAMSIS title only : 0.20
CAMSIS title by status : 0.19
SIOPS : 0.15
ISEI: 0.13
 
*/