* user=****
* password=****
* package=spss
* project=les
set printback=listing .


* UK LES 1989 : SPSS Example CAMSIS matching to UK 89 data.


get file=uk89e .
* Current occ unit (isco88's)=fj04. 
* (incomplete) Employment status info from fj02 and fj06.


* Derive employment status indicator.
compute status=fj02.
recode status (1=2) (2=3) (3=7) (else=9).
if (fj06=6 & fj02=1) status=1.
add value labels status 
   1 "Self-Employed gt 25 employees" 
   2 "Self-Employed with employees" 
   3 "Self-Employed no employees" 4 "Manager" 
   6 "Supervisor / foreman" 7 "Employee" 9 "Unknown".
variable label status "Employment status".
cro status by db02.


* Key indexing var is going to be 'iscobst'.
compute iscobst=-999.
if (fj04 > 0 ) iscobst=(fj04*10) + status.
temp.
select if (fj04 > 0).
means tables=iscobst by status. 



* Match on to CAMSIS scores using index var. 
sort cases by iscobst.
sav out=cstemp .
get file="u:/camsis/csukes89.sav" .
descriptives var=all. 
sort cases by iscobst.
match files table=* /in=csocc 
     /file=cstemp /in=source /by=iscobst.
fre var=csocc source.
cro csocc by source.
select if (source=1).
* (this removes those iscobst values which are not
*   represented in the LES sample).
cro source by db02. 

* Current values are within gender. 
* also can make a cross-gender CAMSIS variable : .
compute cgentcs=-999.
if (db02=1) cgentcs=hitcs.
if (db02=2) cgentcs=witcs. 
compute cgenscs=-999.
if (db02=1) cgenscs=hiscs.
if (db02=2) cgenscs=wiscs. 

* Check distributions.
descriptives var=iscobst cgentcs cgenscs siops isei .
temp. 
select if (fj04 > 0). 
descriptives var=iscobst cgentcs cgenscs siops isei .
temp. 
select if (fj04 > 0 & siops > 0). 
descriptives var=iscobst cgentcs cgenscs siops isei .
* note that the last summary shows us that a handful of cases 
* have occs and camsis scores but have missing siops 
* scores by the ISMF translation.


* Quick assessment: compare values by a UK education recode.
compute educ=et01. 
recode educ (0, 1, 99=1) (2, 3 =2) (5, 6, 7=3).
add value labels educ 
    1 "Primary or less" 2 "Intermediate" 3 "Degree level".
variable label educ "education categories".
select if (educ ge 1).
*cro educ by et01.
fre var=educ. 

temp. 
select if (fj04 > 0).
means tables= cgentcs cgenscs siops isei by educ by db02 
             /statistics=anova.
temp. 
select if (fj04 > 0 & siops > 0 & db02=1).
means tables= cgentcs cgenscs siops isei by educ  
             /statistics=anova.

temp. 
select if (fj04 > 0 & siops > 0 & db02=2).
means tables= cgentcs cgenscs siops isei by educ 
             /statistics=anova.

* . 


/* For interest here are the Eta-squared statistics with 
 education from above:

 Men: 
 CAMSIS title only : 0.26
 CAMSIS title by status : 0.25
 SIOPS : 0.26
 ISEI: 0.29
 Women: 
 CAMSIS title only : 0.33
 CAMSIS title by status : 0.29
 SIOPS : 0.30
 ISEI: 0.23
 
*/