** user=**** 
** password=**** 
** package=spss
** project=lis

set printback=listing .

* SPSS Sweden LIS 1995 : Example CAMSIS matching .

get file= sw95p .

* Current occ unit (nykmin's)=pocc.

compute nykmin=-999 .
if (pocc >= 0 ) nykmin=pocc .

* employment status info from plfs and ptypewk, here use former.
* Mostly though have to treat as missing.
compute empst=0.
if (plfs=4) empst=1.
if (plfs=1 | plfs=2 | plfs=3) empst=2.

add value label empst 
   0 "Unknown employment status"
    1 "Self-employed" 
    2 "Employee" .
variable label empst "Employment status".
cro empst by psex.

* Key indexing variables are nykmin and empst.
sort cases by nykmin empst. 

temp.
select if (pocc > 0).
means tables=nykmin by empst  .

sav out= cstemp .
get file="u:/camsis/csswis95.sav" . 
descriptives var=all.
sort cases by nykmin empst.
match files table=* /in=csocc 
     /file=cstemp /in=source /by=nykmin empst.
fre var=csocc source.
cro csocc by source.
select if (source=1).
* (this removes those CAMSIS nykmin by empst values which are not
*   represented in the LIS sample).
cro source by psex. 


* Current values are within gender. 
* also can make a cross-gender CAMSIS variable : .
compute cgentcs=-999.
if (psex=1) cgentcs=mcam .
if (psex=2) cgentcs=fcam .

descriptives var=nykmin empst cgentcs  .
temp.
select if (pocc > 0).
descriptives var= nykmin empst cgentcs .
* We only match CAMSIS scores through the minor group 
* averages to about 78% of valid occs for Sweden 1995. 


* Quick assessment: compare values by an education recode.
* some recode of education .
compute educ=peduc. 

recode educ (1,2=1) (3,4=2) (5,6,7=3) (else=-9).
add value labels educ  
   1 "Elementary" 2 "Intermediate" 3 "Secondary or higher" . 
variable label educ "education categories".
fre var=educ .

temp.
select if (pocc > 0).
descriptives var= educ cgentcs  . 

temp. 
select if (pocc > 0  & psex=1 & educ > 0).
means tables= cgentcs by educ  
             /statistics=anova.

temp. 
select if (pocc > 0  & psex=2 & educ > 0).
means tables= cgentcs  by educ 
             /statistics=anova.





/* For interest here are the Eta-squared statistics 
 with education from above:

Men: 
CAMSIS  : 0.285

Women: 
CAMSIS  :  0.244

 
*/