** user=**** 
** password=**** 
** package=spss
** project=lis

set printback=listing .

* SPSS Sweden LIS 1987 : Example CAMSIS matching .

get file= sw87p .

* Current occ unit (nykmin's)=pocc.

compute nykmin=-999 .
if (pocc >= 0 ) nykmin=pocc .

* Limited employment status info from  ptypewk.
* Mostly though have to treat as missing.
compute empst=0.
if (plfs=79) empst=1.


add value label empst 
   0 "Unknown employment status"
    1 "Self-employed" 
    2 "Employee" .
variable label empst "Employment status".
cro empst by psex.

* Key indexing variables are nykmin and empst.
sort cases by nykmin empst. 

temp.
select if (pocc > 0).
means tables=nykmin by empst  .

sav out= cstemp .
get file="u:/camsis/csswis87.sav" . 
descriptives var=all.
sort cases by nykmin empst.
match files table=* /in=csocc 
     /file=cstemp /in=source /by=nykmin empst.
fre var=csocc source.
cro csocc by source.
select if (source=1).
* (this removes those CAMSIS nykmin by empst values which are not
*   represented in the LIS sample).
cro source by psex. 


* Current values are within gender. 
* also can make a cross-gender CAMSIS variable : .
compute cgentcs=-999.
if (psex=1) cgentcs=mcam .
if (psex=2) cgentcs=fcam .

descriptives var=nykmin empst cgentcs  .
temp.
select if (pocc > 0).
descriptives var= nykmin empst cgentcs .
* for the 1987 dataset, we match all occs successfully with 
* camsis scores (unlike the 1992 and 1995 datasets).

/* 
* Quick assessment: compare values by an education recode.
* some recode of education .
compute educ=peduc. 
** For Sweden 87 LIS, there is no educ info. 
*/