** user=**** 
** password=**** 
** package=spss
** project=lis



* Slovenian LIS 1997 : Example CAMSIS matching .
* Occ var index is isco88, used is pocc with submaj isco88 in 4 dig.
* Slovene CAMSIS uses employment status 0 - unknown, 
*  1 - self-employed, 6 - employee . 
* CAMSIS index file used, though, comes from LES99.

* To repeat for Slovenia 1999 LIS use same camsis file but change
* LIS file to si99p. 

get file= si97p .

* Current occ unit (isco88)=pocc. 

* Employment status info from plfs .
compute empst=plfs.
recode empst (2,3=1) (1=6) (else=0) .

add value labels empst 
    0 "Unknown" 
   1 "Self-employed"
    6 "Employee" .
variable label empst "Employment status".
fre var=empst.

compute isco88=-999.
if (pocc > 0 ) isco88=pocc .
temp.
select if (pocc > 0).
means tables=isco88 by empst.
sort cases by isco88 empst.
sav out= cstemp .
get file="u:/camsis/cssles99.sav" .
descriptives var=all.
sort cases by isco88 empst.
match files table=* /in=csocc 
     /file=cstemp /in=source /by=isco88 empst.
fre var=csocc source.
cro csocc by source.
select if (source=1).
* (this removes those occbst values which are not
*   represented in the LES sample).
cro source by psex. 

* Current values are within gender. 
* also can make a cross-gender CAMSIS variable : .
compute cgentcs=-999.
if (psex=1) cgentcs=mcam.
if (psex=2) cgentcs=fcam. 

descriptives var=isco88 empst cgentcs  siops isei .
temp. 
select if (pocc > 0). 
descriptives var=isco88 empst cgentcs  siops isei .
temp. 
select if (pocc > 0 & siops > 0). 
descriptives var=isco88 empst cgentcs  siops isei .



* Quick assessment : compare values by an education recode.
compute educ=peduc. 
recode educ   (1,2,3=1) (4,5=2) (6,7,8=3) (else=-9)  .
add value labels educ  
   1 "Primary or less" 2 "Intermediate" 
   3 "High or Degree level " -999 "Unknown".  
variable label educ "education categories".
fre var= educ .

descriptives var= educ cgentcs  siops isei .

temp. 
select if (pocc > 0 & siops > 0 & psex=1 & educ > 0).
means tables= cgentcs  siops isei by educ  
             /statistics=anova.

temp. 
select if (pocc > 0 & siops > 0 & psex=2 & educ > 0).
means tables= cgentcs siops isei by educ 
             /statistics=anova.
 




/* For interest here are the Eta-squared statistics with education from above:

Men: 
CAMSIS : 0.422
SIOPS : 0.393
ISEI: 0.432

Women: 
CAMSIS : 0.489
SIOPS : 0.470
ISEI: 0.529
 
*/