* user=****
* password=****
* package=spss
* project=les
set printback=listing .

get file=sk95e .

* Slovakia Example CAMSIS matching. 
* Current occ unit (isco88's 4 digit)=fj04. 
* (no role to empst for Slovak data).


compute isco88=-999.
if (fj04 > 0 & fj04 < 9400) isco88=fj04.
temp.
select if (fj04 > 0 & fj04 < 9400).
means tables=isco88 by db02. 

sort cases by isco88 .
sav out=cstemp .
get file="u:/camsis/csskes95.sav" .
descriptives var=all. 

sort cases by isco88 .
match files table=* /in=csocc 
     /file=cstemp /in=source /by=isco88 .
fre var=csocc source.
cro csocc by source.
select if (source=1).
* (this removes those iscobst values which are not
*   represented in the LES sample).
cro source by db02. 

* Current values are within gender. 
* also can make a cross-gender CAMSIS variable : .
compute cgentcs=-999.
if (db02=1) cgentcs=mcam.
if (db02=2) cgentcs=fcam. 

descriptives var=isco88 cgentcs siops isei .
temp. 
select if (fj04 > 0 & fj04 < 9400). 
descriptives var=isco88 cgentcs  siops isei .
temp. 
select if (fj04 > 0 & fj04 < 9400 & siops > 0). 
descriptives var=isco88 cgentcs  siops isei .

* Quick assessment: compare values by an education recode.
compute educ=et01. 
recode educ (1,2=1) (3,4,5,6 =2) (7,8=3).
add value labels educ 
    1 "Primary or less" 2 "Intermediate" 3 "Degree level".
variable label educ "education categories".
select if (educ ge 1).
*cro educ by et01.
fre var=educ. 

temp. 
select if (fj04 > 0 & fj04 < 9400 & educ > 0).
means tables= cgentcs siops isei by educ by db02 
             /statistics=anova.
temp. 
select if (fj04 > 0 & fj04 < 9400 & siops > 0 & db02=1 & educ > 0).
means tables= cgentcs  siops isei by educ  
             /statistics=anova.

temp. 
select if (fj04 > 0 & fj04 < 9400 & siops > 0 & db02=2 & educ > 0).
means tables= cgentcs  siops isei by educ 
             /statistics=anova.

* . 


/* For interest here are the Eta-squared statistics with 
 education from above:

 Men: 
 CAMSIS  : 0.441
 SIOPS : 0.368
 ISEI: 0.451

 Women: 
 CAMSIS  : 0.486
 SIOPS : 0.493
 ISEI: 0.507
 
*/