** user=**** 
** password=**** 
** package=spss
** project=lis

set printback=listing .

* SPSS Ireland LIS 1994 : Example CAMSIS matching .

get file= ie94p .

* Ireland LIS 1994 : Example CAMSIS matching .
* (here to person file, applies equally to household file occ vars).
* Just change the year on ie**p file to work for 1995 or 96 LIS.


compute isco88=-999 .
if (pocc > 0 & pocc < 9400) isco88=pocc .

* Current occ unit (isco88 two digit in four digits)=pocc, 
* valid pocc in range > 1000 and < 9400, 
* Employment status differences not applicable to Ireland,


* Key indexing variable is isco88.
sort cases by isco88. 

temp.
select if (pocc > 0 & pocc < 9400).
means tables=isco88 by psex  .

sav out= cstemp .
get file="u:/camsis/csieis94.sav" . 
descriptives var=all.
sort cases by isco88.
match files table=* /in=csocc 
     /file=cstemp /in=source /by=isco88.
fre var=csocc source.
cro csocc by source.
select if (source=1).
* (this removes those CAMSIS isco88 by empst values which are not
*   represented in the LIS sample).
cro source by psex. 


* Current values are within gender. 
* also can make a cross-gender CAMSIS variable : .
compute cgentcs=-999.
if (psex=1) cgentcs=mcam .
if (psex=2) cgentcs=fcam .

descriptives var=isco88 cgentcs  .
temp.
select if (pocc > 0 & pocc < 9400).
descriptives var= isco88 cgentcs .
* We match camsis scores using isco88 averages to ALL cases
* of vaild occs in this sample. 


* Quick assessment: compare values by an education recode.
* some recode of education .
compute educ=peduc. 

recode educ (1=1) (2,3=2) (4,5,6=3) (else=-9).
add value labels educ  
   1 "Elementary" 2 "Intermediate" 3 "High secondary or above" . 
variable label educ "education categories".
fre var=educ .

temp.
select if (pocc > 0 & pocc < 9400).
descriptives var= educ cgentcs isei siops  . 

* Men .
temp. 
select if (pocc > 0  & pocc < 9400 & psex=1 & educ > 0).
means tables= cgentcs by educ  
             /statistics=anova.
temp. 
select if (pocc > 0  & pocc < 9400 & psex=1 & educ > 0 & siops > 0).
means tables= isei siops by educ  
             /statistics=anova.

* Women .
temp. 
select if (pocc > 0  & pocc < 9400 & psex=2 & educ > 0).
means tables= cgentcs  by educ 
             /statistics=anova.
temp. 
select if (pocc > 0  & pocc < 9400 & psex=2 & educ > 0 & siops > 0).
means tables= isei siops by educ  
             /statistics=anova.




/* For interest here are the Eta-squared statistics 
 with education from above for the 1994 LIS :

Men: 
CAMSIS  : 0.132 (Irel note: much lower than normal)
ISEI  : 0.342
SIOPS : 0.271

Women: 
CAMSIS  :  0.216
ISEI : 0.234
SIOPS : 0.236
 
*/