** user=**** 
** password=**** 
** package=spss
** project=lis

set printback=listing .

* SPSS Hungary LIS 1994 : Example CAMSIS matching .

get file= hu94p .

* Current occ unit (isco88's)=pocc.

compute isco88=-999 .
if (pocc >= 0 ) isco88=pocc .

* Employment status info from plfs and ptypewk, here use latter.
compute empst=0.
if (ptypewk=2 | ptypewk=5) empst=1.
if (ptypewk=1) empst=2.

add value label empst 
   0 "Unknown employment status"
    1 "Self-employed" 
    2 "Employee" .
variable label empst "Employment status".
cro empst by psex.

* Key indexing variables are isco88 and empst.
sort cases by isco88 empst. 

temp.
select if (pocc > 0).
means tables=isco88 by empst  .

sav out= cstemp .
get file="u:/camsis/cshuis94.sav" . 
descriptives var=all.
sort cases by isco88 empst.
match files table=* /in=csocc 
     /file=cstemp /in=source /by=isco88 empst.
fre var=csocc source.
cro csocc by source.
select if (source=1).
* (this removes those CAMSIS isco88 by empst values which are not
*   represented in the LIS sample).
cro source by psex. 


* Current values are within gender. 
* also can make a cross-gender CAMSIS variable : .
compute cgentcs=-999.
if (psex=1) cgentcs=mcam .
if (psex=2) cgentcs=fcam .

descriptives var=isco88 empst cgentcs siops isei .
temp.
select if (pocc > 0).
descriptives var= isco88 empst cgentcs siops isei .
temp.
select if (pocc > 0 & siops > 0).
descriptives var= isco88 empst cgentcs siops isei . 
* a dozen cases in this file have isco88's but not camsis scores. 

* Quick assessment: compare values by an education recode.
* some recode of education .
compute educ=peduc. 
recode educ (0,1,2,3,4,5=1) (6=2) (7,8,9=3) (else=-9).
add value labels educ  
   1 "Elementary" 2 "Vocational" 3 "Secondary or higher" . 
variable label educ "education categories".
fre var=educ .

temp.
select if (pocc > 0).
descriptives var= educ cgentcs siops isei . 

temp. 
select if (pocc > 0 & siops > 0 & psex=1).
means tables= cgentcs siops isei by educ  
             /statistics=anova.

temp. 
select if (pocc > 0 & siops > 0 & psex=2).
means tables= cgentcs siops isei by educ 
             /statistics=anova.




/* For interest here are the Eta-squared statistics 
 with education from above:

Men: 
CAMSIS  : 0.377
SIOPS : 0.311
ISEI: 0.336
Women: 
CAMSIS  :  0.470
SIOPS : 0.387
ISEI: 0.393
 
*/