** user=**** 
** password=**** 
** package=stata
** project=lis

#delimit;

* GERMANY LIS 1994 : Example CAMSIS matching to DE 94 data;

use $ge94p;
* Current occ unit (isco68 minors)=pocc; 
* (incomplete) Employment status info from ptypewk only;
* BEWARE: PTYPEWK FOR DE94 IS NOT SAME AS FOR DE89;


* Derive Employment status indicator;
tab ptypewk;
gen status=ptypewk;
recode status 21/23=1 24=2 25=3 51/55=4 *=9;
*recode status 21/23=1 24=2 25=3 51/55=4 11/15 31/46=5 *=9;
* the latter is an alternative handling of employees;

label define stat 
   1 "Self-Employed, no employees"
   2 "Self-Employed, with employees"
   3 "Family Assistant"
   4 "Public service"
   5 "Employee (contract)"
   6 "Worker (non-contract)" 
   9 "Unknown";
label values status stat;
label variable status "Employment status";
tab status psex;




* Key indexing variable is minbst;
gen minbst=-999;
replace minbst=pocc*10 + status if (pocc > 0 );
tabulate status if (pocc > 0 ), 
       summarize(minbst) mean standard freq ;



* Match this file with CAMSIS scores file; 
sort minbst;
save cstemp, replace;
use minbst hrcs wrcs htcs wtcs siopsm iseim 
      using $mydata\camsis\csdeis94;
summarize;
sort minbst;
merge minbst using cstemp;
gen occinfo=_merge;
tab occinfo; 
drop if (occinfo==1);
* (this removes those minbst values which are not represented in the LES sample);
tab occinfo psex; 




* Current values are within gender; 
* also can make a cross-gender CAMSIS variable : ;
gen cgentcs=-999;
replace cgentcs=htcs if (psex==1);
replace cgentcs=wtcs if (psex==2);
gen cgenscs=-999;
replace cgenscs=hrcs if (psex==1);
replace cgenscs=wrcs if (psex==2);
summarize minbst cgentcs cgenscs siopsm iseim ;
summarize minbst cgentcs cgenscs siopsm iseim if pocc > 0;
summarize minbst cgentcs cgenscs siopsm iseim if (pocc > 0 & siopsm > 0); 
* note that the last summary shows us that there are quite a lot 
* of cases with occs but without camsis or isei, also some with  
*  camsis scores but have missing siops scores by the ISMF translation;




* Quick assessment: compare values by an education recode;
di "Education";
* some recode of education ;
gen educ=peduc; 
recode educ 0 1 2=1 3/8=2 9/15=3 *=-9;
label define edu  1 "None or low level" 2 "Intermediate" 
 3 "Higher and/or University"; 
label values educ edu;
label variable educ "Germany education categories";
tab educ ;
sort psex;
by psex:
  summarize educ 
      cgentcs cgenscs siopsm iseim if pocc > 0; 
by psex: 
 oneway cgentcs educ  if (pocc > 0), tabulate;
by psex: 
 oneway cgenscs educ  if (pocc > 0), tabulate;
by psex: 
 oneway siopsm educ  if (pocc > 0 & siopsm > 0), tabulate;
by psex: 
 oneway iseim educ  if (pocc > 0 & iseim > 0), tabulate;




/* For interest here are the Eta-squared statistics with education from above:

Men: 
CAMSIS title only : 0.
CAMSIS title by status : 0.
SIOPS : 0.
ISEI: 0.
Women: 
CAMSIS title only : 0.
CAMSIS title by status : 0.
SIOPS : 0.
ISEI: 0.
 
*/