** user=**** 
** password=**** 
** package=spss
** project=lis

set printback=listing .


* GERMANY LIS 1994 : SPSS Example CAMSIS matching to DE 94 data;

get file= ge94p .
* Current occ unit (isco68 minors)=pocc. 
* (incomplete) Employment status info from ptypewk only.


* Derive employment status indicator.
fre var= ptypewk.
compute status=ptypewk.
recode status (21 thru 23=1) (24=2) (25=3)
           (51 thru 55=4) (else=9) .
*recode status (21 thru 23=1) (24=2) (25=3)
           (51 thru 55=4) (11 thru 15, 31 thru 46=5) (else=9) .
* the latter is an alternative handling of employees.
add value labels status 
   1 "Self-Employed, no employees"
   2 "Self-Employed, with employees"
   3 "Family Assistant"
   4 "Public service"
   5 "Employee (contract)"
   6 "Worker (non-contract)" 
   9 "Unknown".
variable label status "Employment status".
cro status by psex.


* Key indexing variable is minbst.
compute minbst=-999.
if (pocc > 0 ) minbst=pocc*10 + status .
temp. 
select if (pocc > 0).
means tables=minbst by status . 

* MAtch with CAMSIS files. 
sort cases by minbst.
sav out= cstemp .
get file="u:/camsis/csdeis94.sav" . 
descriptives var=all.
sort cases by minbst.
match files table=* /in=csocc 
     /file=cstemp /in=source /by=minbst.
fre var=csocc source.
cro csocc by source.
select if (source=1).
* (this removes those occbst values which are not
*   represented in the LIS sample).
cro source by psex. 



* Adjust: Current values are within gender, 
* also can make a cross-gender CAMSIS variable : .
compute cgentcs=-999.
if (psex=1) cgentcs=htcs .
if (psex=2) cgentcs=wtcs .
compute cgenscs=-999.
if (psex=1) cgenscs=hrcs .
if (psex=2) cgenscs=wrcs .


* Check coverage of variables.
descriptives var= minbst cgentcs cgenscs siops isei .
temp. 
select if (pocc > 0).
descriptives var= minbst cgentcs cgenscs siops isei .
temp. 
select if (pocc > 0 & siops > 0).
descriptives var= minbst cgentcs cgenscs siops isei . 
* note that the last summary shows us that there are quite a lot 
* of cases with occs but without camsis or isei, also some with  
*  camsis scores but have missing siops by ISMF translation.


* Quick assessment: compare values by education recode.
* (national specific) .
compute educ=peduc. 
recode educ (0,1,2=1) (3 thru 8=2) (9 thru 15=3) (else=-9) .
add value labels educ  1 "None or low level" 2 "Intermediate" 
          3 "Higher and/or University".
variable label educ "Germany education categories".
fre var=educ .

temp.
select if (pocc > 0).
descriptives var= educ cgentcs cgenscs siops isei . 

temp. 
select if (pocc > 0 & siops > 0 & psex=1).
means tables= cgentcs cgenscs siops isei by educ  
             /statistics=anova.

temp. 
select if (pocc > 0 & siops > 0 & psex=2).
means tables= cgentcs cgenscs siops isei by educ 
             /statistics=anova.




/* For interest here are the Eta-squared statistics with education from above:

Men: 
CAMSIS title only : 0.27
CAMSIS title by status : 0.20
SIOPS : 0.27
ISEI: 0.34
Women: 
CAMSIS title only : 0.10
CAMSIS title by status : 0.09
SIOPS : 0.17
ISEI: 0.18
 
*/