** user=**** 
** password=**** 
** package=stata
** project=lis

#delimit;


* Czech LIS 1992 : Example CAMSIS matching ;
* This example on the person file, change var names to use hhld file;
* Occ var index is isco88, used is pocc with isco88 2 digit groups;
* Czech data has employment status 0 - unknown, 
*  1 - self-employed, 6 - employee ; 

use $cz92p;


* Employment status info from ptypewk ;
gen empst=ptypewk;
recode empst 3 4 5 6=1 1 2=6 *=0 ;
label define stat 
   0 "Unknown" 
   1 "Self-employed"
   6 "Employee";
label values empst stat;
label variable empst "Employment status";
tab empst psex;


gen isco88=-999;
replace isco88=pocc if (pocc > 0 );
tabulate empst if (pocc > 0 ), 
       summarize(isco88) mean standard freq ;

sort isco88 empst;
save cstemp, replace;
clear;
infile isco88 empst mcam fcam siops isei 
      using $mydata\camsis\csczis92.dat;
summarize;
sort isco88 empst;
merge isco88 empst using cstemp;
gen occinfo=_merge;
tab occinfo; 
drop if (occinfo==1);
* (this removes those occbst values which are not represented in the LES sample);
tab occinfo psex; 

* Current values are within gender; 
* also can make a cross-gender CAMSIS variable : ;
gen cgentcs=-999;
replace cgentcs=mcam if (psex==1);
replace cgentcs=fcam if (psex==2);

summarize isco88 empst cgentcs siops isei ;
summarize isco88 empst cgentcs siops isei if pocc > 0;
summarize isco88 empst cgentcs siops isei if (pocc > 0 & siops > 0); 


* Quick assessment : compare values by an education recode;
gen educ=peduc; 
recode educ 1=1 2 3=2 4 5 6=3 *=-9;
label define edu  1 "Elementary" 2 "Intermediate" 
  3 "Higher level" -9 "Unknown"; 
label values educ edu;
label variable educ "education categories";
tab  educ  ;

sort psex;
by psex:
  summarize educ 
      cgentcs siops isei if pocc > 0; 
by psex: 
 oneway cgentcs educ  if (pocc > 0 & educ > 0), tabulate;

by psex: 
 oneway siops educ  if (pocc > 0 & siops > 0 & educ > 0), tabulate;
by psex: 
 oneway isei educ  if (pocc > 0 & isei > 0 & educ > 0), tabulate;