** user=**** 
** password=**** 
** package=spss
** project=lis

set printback=listing .

* SWITZERLAND LIS 1992 : Example CAMSIS matching to CH 92 data.

get file= ch92p .
* Current occ unit (btap minors)=pocc.

* most Employment status info available on plfs.
compute empst=plfs.
recode empst (1,2=1) (3,5,6=6) (4=5) (else=0) .
add value labels empst 0 "Status unknown"
   1 "Self-employed (all)"
   2 "Self-Employed (principals)" 
   5 "Family Assistant" 
   6 "Employee" .
variable label empst "Employment status".
cro empst by psex.

* Key indexing variables empst and btap (pocc).
compute btap=-999.
if (pocc > 0 ) btap=pocc .
temp.
select if (pocc > 0) .
means tables=btap by empst  .
sort cases by btap empst.
sav out= cstemp .
get file="u:/camsis/cschis92.sav" . 
descriptives var=all.
sort cases by btap empst.
match files table=* /in=csocc 
     /file=cstemp /in=source /by=btap empst.
fre var=csocc source.
cro csocc by source.
select if (source=1).
* (this removes those empst by btap values which are not
*   represented in the LIS sample).
cro source by psex. 


* Current values are within gender; 
* also can make a cross-gender CAMSIS variable : .
compute cgentcs=-999.
if (psex=1) cgentcs=mcam .
if (psex=2) cgentcs=fcam .



descriptives var= btap empst cgentcs siops isei .
temp. 
select if (pocc > 0).
descriptives var= btap empst cgentcs siops isei .
temp. 
select if (pocc > 0 & siops > 0).
descriptives var= btap empst cgentcs siops isei . 
* handful of cases have occs but we can't get a camsis score. 
temp. 
select if (pocc > 0 & siops > 0 & cgentcs > 0).
descriptives var= btap empst cgentcs siops isei . 
* all with camsis also get isei / siops.
missing values cgentcs  (-999).

* Quick assessment: compare values by an education recode.

* some recode of education .
compute educ=peduc. 
recode educ (0,1=1) (2,3,4,5,7,8,9=2) 
       (6,10,11,12,13,14,15=3) .
add value labels educ  1 "Primary or less" 2 "Intermediate" 
                 3 "High or Degree level " . 
variable label educ "education categories".
fre var= educ  .
* note high level of missing data, 50 percent of cases.
* this is because this var is only collected for household heads.
fre var=psex.
* note a couple of missing psexes.
select if (psex = 1 | psex =2).
fre var=psex.



temp.
select if (pocc > 0).
descriptives var= educ cgentcs  siops isei . 

temp. 
select if (pocc > 0 & siops > 0 & psex=1).
means tables= cgentcs siops isei by educ  
             /statistics=anova.

temp. 
select if (pocc > 0 & siops > 0 & psex=2).
means tables= cgentcs siops isei by educ 
             /statistics=anova.




/* For interest here are the Eta-squared statistics with 
 education from above:

Men: 
CAMSIS : 0.275
SIOPS : 0.199
ISEI: 0.209
Women: 
CAMSIS : 0.181
SIOPS : 0.138
ISEI: 0.090
 
*/