** user=**** 
** password=**** 
** package=spss
** project=les



* Austrian LES 1991 : Example CAMSIS matching .
* This example on the person file, change var names to use hhld file.
* Occ var index is isco88, used is pocc with isco88 in 4 dig.
* Austrian data has employment status 0 - unknown, 
*  1 - self-employed, 6 - employee . 


get file= at91e .

* Current occ unit (isco88)=fj04. 

* Employment status info from fj02 .
compute empst=fj02.
recode empst (1,4=1) (3=6) (else=0) .

add value labels empst 
    0 "Unknown" 
   1 "Self-employed"
    6 "Employee" .
variable label empst "Employment status".
fre var=empst.

compute isco88=-999.
if (fj04 > 0 ) isco88=fj04 .
temp.
select if (fj04 > 0).
means tables=isco88 by empst.
sort cases by isco88 empst.
sav out= cstemp .
get file="u:/camsis/csates91.sav" .
descriptives var=all.
sort cases by isco88 empst.
match files table=* /in=csocc 
     /file=cstemp /in=source /by=isco88 empst.
fre var=csocc source.
cro csocc by source.
select if (source=1).
* (this removes those occbst values which are not
*   represented in the LES sample).
cro source by db02. 

* Current values are within gender. 
* also can make a cross-gender CAMSIS variable : .
compute cgentcs=-999.
if (db02=1) cgentcs=mcam.
if (db02=2) cgentcs=fcam. 

descriptives var=isco88 empst cgentcs  siops isei .
temp. 
select if (fj04 > 0). 
descriptives var=isco88 empst cgentcs  siops isei .
temp. 
select if (fj04 > 0 & siops > 0). 
descriptives var=isco88 empst cgentcs  siops isei .




* Quick assessment : compare values by an education recode.
compute educ=et01. 
recode educ   (1=1) (3,4,5=2) (6=3) (else=-9)  .
add value labels educ  
   1 "Primary or less" 2 "Intermediate" 
   3 "High or Degree level " -999 "Unknown".  
variable label educ "education categories".
fre var= educ .

descriptives var= educ cgentcs  siops isei .

temp. 
select if (fj04 > 0 & siops > 0 & db02=1 & educ > 0).
means tables= cgentcs  siops isei by educ  
             /statistics=anova.

temp. 
select if (fj04 > 0 & siops > 0 & db02=2 & educ > 0).
means tables= cgentcs siops isei by educ 
             /statistics=anova.
 




/* For interest here are the Eta-squared statistics with education from above:

Men: 
CAMSIS : 0.441
SIOPS : 0.350
ISEI: 0.395

Women: 
CAMSIS : 0.449
SIOPS : 0.352
ISEI: 0.340
 
*/